أكاديمية الصقر للتدريب

لوحة التميز الأسبوعي
العضو المتميز المشرف المتميز المراقب المتميز المدير المتميز الموضوع المتميز القسم المتميز
العضو المتميز المشرف المتميز المراقب المتميز المدير المتميز الموضوع المتميز القسم المتميز
محمدعبدالسلام لا تميز خلال هذه الفترة-- لا تميز خلال هذه الفترة لا تميز خلال هذه الفترة طلب مساعدة اريد في كل 4 من شهر يتم نسح الاسم من عمود الى عمود اكسيل اسئله واجابات


أهلا وسهلا بك زائرنا الكريم في أكاديمية الصقر للتدريب، لكي تتمكن من المشاركة ومشاهدة جميع أقسام المنتدى وكافة الميزات ، يجب عليك إنشاء حساب جديد بالتسجيل بالضغط هنا أو تسجيل الدخول اضغط هنا إذا كنت عضواً .





تعديل كود اضافة صف للإجمالى مرتين خلال نفس الشهر

السلام عليكم اساتذتى الكرام واسف جداً على ازعاج حضراتكم ... أتمنى من الله وبجهودكم مساعدتى فى ضبط عمل هذا الكود بإدخال ص ..


موضوع مغلق

الصفحة 1 من 2 < 1 2 > الأخيرة »


09-08-2020 08:37 مساء
هانى على
عضو ماسي
rating
معلومات الكاتب ▼
تاريخ الإنضمام : 10-03-2018
رقم العضوية : 4794
المشاركات : 480
الجنس : ذكر
تاريخ الميلاد : 1-4-1980
يتابعهم : 5
يتابعونه : 4
قوة السمعة : 855
عدد الإجابات: 8
 offline 

السلام عليكم اساتذتى الكرام واسف جداً على ازعاج حضراتكم ... أتمنى من الله وبجهودكم مساعدتى فى ضبط عمل هذا الكود بإدخال صف لإجمالة العمليات التى تمت منذ بداية الشهر وحتى منتصف الشهر
والمرة الأخرى من بعد منتصف الشهر الى اخر نفس الشهر ... والصورة المرسلة مع الملف تبين وتوضح طلبى بالضبط , واريد ان يكون اضافة صف الإجمالى كما هو موضح بالطريقة اليدوية Manuel
ملحوظة : هذا يعتبر ملف مصغر للملف الأصلى كمثال ... فالملف الأصلى يحتوى على عدة صفحات بأسماء شركات النقل المختلفة

ولكم منى جزيل الشكر

Private Sub Do_It()
    With Application
        cm = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
    End With
    With ActiveSheet
        a_max = .Cells(.Rows.Count, "A").End(xlUp).Row
        For a = a_max To 3 Step -1
            If .Cells(a, "A") = "Total" Then
                With .Range("A" & a & ":T" & a)
                    .ClearContents
                    .Interior.ColorIndex = xlNone
                    .Font.ColorIndex = 1
                End With
            End If
        Next a
        With .Sort
            .SortFields.Clear
'            .SortFields.Add2 Key:=Range("A3:A" & a_max), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
            .SetRange Range("A2:T" & a_max)
            .Header = xlYes
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
        d_min = WorksheetFunction.Min(.Range("A3:A" & a_max))
        d_max = Date
        dd = True
        a = 2
        For d = d_min To d_max
            If dd Then
                d1 = CLng(DateSerial(Year(d), Month(d), 1))
                d2 = CLng(DateSerial(Year(d), Month(d), 16))
            Else
                d1 = CLng(DateSerial(Year(d), Month(d), 16))
                d2 = CLng(DateSerial(Year(d), Month(d) + 1, 1))
            End If
            If d1 <= d_max Then
                Do
                    a = a + 1
                Loop Until .Cells(a + 1, "A") >= d2 Or .Cells(a, "A") = Empty
                a_max = a_max + 1
                .Rows(a & ":" & a).Insert Shift:=xlDown, CopyOrigin:=xlFormatFromLeftOrAbove
                If a = 3 Then
                    .Range("A4:T4").Copy
                    .Range("A3").PasteSpecial Paste:=xlPasteFormats, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
                End If
                a3a = "A3:A" & a_max
                dd = Not dd
                .Cells(a, "A") = "Total"
                .Range("A" & a & ":R" & a).Interior.ColorIndex = 6
                With .Range("S" & a & ":T" & a)
                    .Interior.ColorIndex = 11
                    .Font.ColorIndex = 2
                End With
                For x = 2 To 20
                    s = WorksheetFunction.SumIfs(.Range(.Cells(3, x), .Cells(a_max, x)), .Range(a3a), ">=" & d1, .Range(a3a), "<" & d2)
                    .Cells(a, x) = s
                    If x = 17 Then x = x + 1
                Next x
            End If
            d = d2
        Next d
        .Range("AA1:AA2").Activate
    End With
    With Application
        .Calculation = cm
        .ScreenUpdating = True
    End With
End Sub

Kw9q4_1
لمشاهدة الروابط يلزمك التسجيل في أكاديمية الصقر للتدريب
 
 
  TransportatioCompanies1.xlsm   تحميل xlsm مرات التحميل :(1)
الحجم :(114.469) KB



أفضل إجابة مقدمة من salim وهي:
تم معالجة الامر
اما بشأن السطر الاحمر  لم افهم ماذا تريد لأنه يوجد عدة اشهر
كما هو واضح من الصورة( شهر 6 / 7/ 10 /11)
 
عرض الإجابة




10-08-2020 07:04 مساء
مشاهدة مشاركة منفردة [1]
salim
خبير معتمد
rating
معلومات الكاتب ▼
تاريخ الإنضمام : 22-08-2017
رقم العضوية : 43
المشاركات : 853
الجنس : ذكر
تاريخ الميلاد : 1-5-1989
الدعوات : 1
يتابعهم : 13
يتابعونه : 33
قوة السمعة : 6607
عدد الإجابات: 67
 offline 
look/images/icons/i1.gif تعديل كود اضافة صف للإجمالى مرتين خلال نفس الشهر
1- يحب ادراج صف فارغ تماماً( الصف 2 ) وذلك لفصل الجدول عن الخلايا المدمجة وجعل الجدول ابتداء من الخلية A4 مستقلاً عنها
2- الماكرو

Option Explicit

Dim sh As Worksheet
Dim Max_ro%, New_ro%, I%, Mth, E_Mth
Dim rg As Range, del_rg As Range
Dim Last_date
Dim my_day
Const TOT = "TOTAL"
Const dy = 15
'"""""""""""""""""""""""""""""""""""""
Sub get_total()
Set sh = Sheets("Limousin Agent")

 If sh.AutoFilterMode Then
 sh.Range("a3").AutoFilter
 End If
 sh.Range("A3:Q10000").Interior.ColorIndex = xlNone
Max_ro = sh.Cells(Rows.Count, 1).End(3).Row
If Max_ro < 4 Then Exit Sub
Set rg = sh.Range("A3:T" & Max_ro)
 rg.AutoFilter 1, TOT
 On Error Resume Next
 sh.Range("a4:A" & Max_ro).SpecialCells(12).EntireRow.Delete

 On Error GoTo 0
 rg.AutoFilter
End Sub
'+++++++++++++++++++++++++++
Sub Sort_data()
get_total
New_ro = sh.Cells(Rows.Count, 1).End(3).Row
 sh.Range("A3:T" & New_ro).Sort key1:=sh.Range("A3"), Header:=xlYes
End Sub
'+++++++++++++++++++++++++++
Sub Insert_rows()
Dim x As Boolean, y As Boolean, z As Boolean
Dim t%

 Sort_data
 New_ro = sh.Cells(Rows.Count, 1).End(3).Row
 t = 4
 For I = 4 To New_ro

  If IsDate(sh.Cells(I, 1)) Then
   Mth = Month(sh.Cells(I, 1))
   Last_date = DateSerial(Year(sh.Cells(I, 1)), Mth + 1, 0)
   E_Mth = Month(Last_date)
   my_day = Day(Last_date)
    x = Mth = E_Mth
    y = Day(sh.Cells(I, 1)) = dy Or Day(sh.Cells(I, 1)) = my_day
    z = sh.Cells(I, 1) <> sh.Cells(I + 1, 1)
    If x * y * z = -1 Then
    sh.Cells(I + 1, 1).Insert
    sh.Cells(I + 1, 1) = TOT
    sh.Cells(I + 1, 1).Resize(, 17).Interior.ColorIndex = 6
    sh.Cells(I + 1, 2).Resize(, 16).Formula = _
    "=SUM(B" & t & ":B" & I & ")"
    t = I + 2
    End If  'x * y * z
     
  End If 'isdate
  Next
 New_ro = sh.Cells(Rows.Count, 1).End(3).Row + 1
 sh.Cells(New_ro, 1) = TOT
 sh.Cells(New_ro, 1).Resize(, 17).Interior.ColorIndex = 6
 sh.Cells(New_ro, 1).Resize(, 17).Formula = _
 "=SUM(B" & t & ":B" & New_ro - 1 & ")"
 sh.Range("A4").CurrentRegion.Value = _
 sh.Range("A4").CurrentRegion.Value
End Sub

3 لا تنسخ مع الكود ما ظهر فيه بعد End Sub  لانه سطر نزل عشوائياً  لا أعرف من اين   سؤال برسم الإداريين
4 الملف مرفق




 
 
 
  Ali_hani.xlsm   تحميل xlsm مرات التحميل :(3)
الحجم :(556.53) KB


10-08-2020 10:21 مساء
مشاهدة مشاركة منفردة [2]
salim
خبير معتمد
rating
معلومات الكاتب ▼
تاريخ الإنضمام : 22-08-2017
رقم العضوية : 43
المشاركات : 853
الجنس : ذكر
تاريخ الميلاد : 1-5-1989
الدعوات : 1
يتابعهم : 13
يتابعونه : 33
قوة السمعة : 6607
عدد الإجابات: 67
 offline 
look/images/icons/i1.gif تعديل كود اضافة صف للإجمالى مرتين خلال نفس الشهر
تم معالجة الخطأ في الكود
  انتبة الى الصف رقم 2 (مخفي) يجب ان يكون فارغاً من اي شيء


Option Explicit
'+++++++++++++++++++++++++++++++++
Dim sh As Worksheet
Dim Max_ro%, New_ro%, I%, Mth, E_Mth
Dim rg As Range, del_rg As Range
Dim Last_date
Dim my_day
Const TOT = "TOTAL"
Const dy = 15
'"""""""""""""""""""""""""""""""""""""
Sub get_total()
Set sh = Sheets("Limousin Agent")
Max_ro = sh.Cells(Rows.Count, 1).End(3).Row
 sh.Range("A4:Q" & Max_ro).Interior.ColorIndex = xlNone
 For I = Max_ro To 4 Step -1
  If Not IsDate(sh.Cells(I, 1)) Then
   sh.Cells(I, 1).EntireRow.Delete
  End If
 Next
End Sub
'+++++++++++++++++++++++++++
Sub Sort_data()
get_total
New_ro = sh.Cells(Rows.Count, 1).End(3).Row
 sh.Range("A3:T" & New_ro).Sort key1:=sh.Range("A3"), Header:=xlYes
End Sub
'+++++++++++++++++++++++++++
Sub Insert_rows()
Dim x As Boolean, y As Boolean, z As Boolean
Dim t%, k

 Sort_data
 If sh.AutoFilterMode Then
   sh.Range("a4").AutoFilter
  End If
 
 New_ro = sh.Cells(Rows.Count, 1).End(3).Row
 t = 4
 For I = 4 To New_ro

  If IsDate(sh.Cells(I, 1)) Then
   Mth = Month(sh.Cells(I, 1))
   Last_date = DateSerial(Year(sh.Cells(I, 1)), Mth + 1, 0)
   E_Mth = Month(Last_date)
   my_day = Day(Last_date)
    x = Mth = E_Mth
    y = Day(sh.Cells(I, 1)) = dy Or Day(sh.Cells(I, 1)) = my_day
    z = sh.Cells(I, 1) <> sh.Cells(I + 1, 1)
    If x * y * z = -1 Then
   
    sh.Cells(I + 1, 1).EntireRow.Insert , xlDown
    sh.Cells(I + 1, 1) = TOT
    sh.Cells(I + 1, 1).Resize(, 17).Interior.ColorIndex = 6
    sh.Cells(I + 1, 2).Resize(, 16).Formula = _
    "=SUM(B" & t & ":B" & I & ")"
    t = I + 2: I = I + 1: k = k + 1
    End If  'x * y * z
     
  End If 'isdate
  Next
  
 New_ro = sh.Cells(Rows.Count, 1).End(3).Row + 1
  sh.Cells(New_ro, 1) = TOT
  sh.Cells(New_ro, 1).Resize(, 17).Interior.ColorIndex = 6
  sh.Cells(New_ro, 2).Resize(, 16).Formula = _
    "=SUM(B" & t & ":B" & New_ro - 1 & ")"
   sh.Range("A4:Q" & New_ro).Value = _
   sh.Range("A4:Q" & New_ro).Value
   MsgBox "I Enter " & k + 1 & " " & _
   IIf(k = 1, TOT, "Recordes") & " For you " & Chr(10) & _
   " I hope you say thank you : " & """SALIM"""
End Sub
'+++++++++++++++++++++++++++++++++++
Sub CLEAR_TOTALS()
Dim k%
Set sh = Sheets("Limousin Agent")
Max_ro = sh.Cells(Rows.Count, 1).End(3).Row
 sh.Range("A4:Q" & Max_ro).Interior.ColorIndex = xlNone
 For I = Max_ro To 4 Step -1
  If Not IsDate(sh.Cells(I, 1)) Then
 sh.Cells(I, 1).EntireRow.Delete
   k = k + 1
  End If
 Next
  MsgBox "I Clear " & k & " " & _
   IIf(k = 1, TOT, "Recordes") & " For you " & Chr(10) & _
   " I hope you say thank you : " & """SALIM"""
End Sub


الملف الجديد
 
 
 
  Ali_hani_Super.xlsm   تحميل xlsm مرات التحميل :(2)
الحجم :(552.074) KB


10-08-2020 11:10 مساء
مشاهدة مشاركة منفردة [3]
salim
خبير معتمد
rating
معلومات الكاتب ▼
تاريخ الإنضمام : 22-08-2017
رقم العضوية : 43
المشاركات : 853
الجنس : ذكر
تاريخ الميلاد : 1-5-1989
الدعوات : 1
يتابعهم : 13
يتابعونه : 33
قوة السمعة : 6607
عدد الإجابات: 67
 offline 
look/images/icons/i1.gif تعديل كود اضافة صف للإجمالى مرتين خلال نفس الشهر
انسخ الكود الى كل صفحة من ملفك (ليس في Module مستقل بل في Module الصفحة ذاتها) مع تغيير
Set sh = Sheets("Limousin Agent")  الى اسم الصفحة ولا تنسى الصف الثاني فارغ

10-08-2020 11:15 مساء
مشاهدة مشاركة منفردة [4]
هانى على
عضو ماسي
rating
معلومات الكاتب ▼
تاريخ الإنضمام : 10-03-2018
رقم العضوية : 4794
المشاركات : 480
الجنس : ذكر
تاريخ الميلاد : 1-4-1980
يتابعهم : 5
يتابعونه : 4
قوة السمعة : 855
عدد الإجابات: 8
 offline 
look/images/icons/i1.gif تعديل كود اضافة صف للإجمالى مرتين خلال نفس الشهر
أحسنت استاذ سليم ... انه حقاً كود رائع  بارك الله فيك وزادك الله من فضله مجهود ممتاز جعله الله فى ميزان حسناتك ورحم الله والديك
ولكن هذه المشكلة قد تقابلنى دائماً انه اذا انتهت التشغيلات مثلاً الى يوم قبل منتصف الشهر
او قبل نهاية الشهر يقوم الكود بدمج هذه التشغيلات داخل صف الإجمالى
الذى يسبقها على الرغم انها تكون فى شهر مختلف خالص وذلك كما ترى
استاذى الكريم بالصورة بالصفين باللون الأحمر

sRg52_1

 
 


11-08-2020 08:29 صباحا
مشاهدة مشاركة منفردة [5]
salim
خبير معتمد
rating
معلومات الكاتب ▼
تاريخ الإنضمام : 22-08-2017
رقم العضوية : 43
المشاركات : 853
الجنس : ذكر
تاريخ الميلاد : 1-5-1989
الدعوات : 1
يتابعهم : 13
يتابعونه : 33
قوة السمعة : 6607
عدد الإجابات: 67
 offline 
look/images/icons/i1.gif تعديل كود اضافة صف للإجمالى مرتين خلال نفس الشهر
1-تم التعديل على الملف مع اضافة على الماكرو ليمسح اخر مجموع اذا لم يكن يحتوي على 15 او اخر الشهر
2-ماكرو واحد لجميع الصفحات  ذلك باستبدال

Set sh = Sheets("Limousin Agent")

بعبارة 

Set sh = ActiveSheet

3- يتم ايقاف الماكرو اذا كان تصميم الـــ Sheet مخالف 
لتصميم Limousin Agent مع اظهار رسالة بهذا الأمر
نسخ الأزرار من Limousin Agent الى باقي الشيتات
لتقوم هذه الازرار بتنفيذ نفس الماكرو
6- كل ما عليك اعادة تسمية بقية الشيتات بالاسماء التي تريدها مع امكانية اضافة شيتات اخرى
7 الماكرو الكامل

Option Explicit
'+++++++++++++++++++++++++++++++++
Dim sh As Worksheet
Dim Max_ro%, New_ro%, I%, Mth, E_Mth
Dim rg As Range, del_rg As Range
Dim Last_date
Dim my_day
Const TOT = "TOTAL"
Const dy = 15
'"""""""""""""""""""""""""""""""""""""
Sub get_total()
Set sh = ActiveSheet
Max_ro = sh.Cells(Rows.Count, 1).End(3).Row
 sh.Range("A4:Q" & Max_ro).Interior.ColorIndex = xlNone
 For I = Max_ro To 4 Step -1
  If Not IsDate(sh.Cells(I, 1)) Then
   sh.Cells(I, 1).EntireRow.Delete
  End If
 Next
End Sub
'+++++++++++++++++++++++++++
Sub Sort_data()
get_total
New_ro = sh.Cells(Rows.Count, 1).End(3).Row
 sh.Range("A3:T" & New_ro).Sort key1:=sh.Range("A3"), Header:=xlYes
End Sub
'+++++++++++++++++++++++++++
Sub Insert_rows()
Set sh = ActiveSheet
'//////////////////////////////////
If sh.Range("A3") <> "Date" _
 Or sh.Range("B3") <> "Hurghada" _
 Or sh.Range("A2") <> "" Then
  MsgBox "YOU HAVE DIFFERENT STRUCTURE OF SHEET" & Chr(10) & _
  "MAKE THE SAME STRUCTURE OF THE SHEET :" & """ Limousin Agent"""
  Exit Sub
 End If

'//////////////////////////////
Dim x As Boolean, y As Boolean, z As Boolean
Dim t%, k, A

 Sort_data
 If sh.AutoFilterMode Then
   sh.Range("a4").AutoFilter
  End If
 
 New_ro = sh.Cells(Rows.Count, 1).End(3).Row
 t = 4
 For I = 4 To New_ro + 1000
   If sh.Cells(I, 1) = vbNullString Then Exit For
  If IsDate(sh.Cells(I, 1)) Then
   Mth = Month(sh.Cells(I, 1))
   Last_date = DateSerial(Year(sh.Cells(I, 1)), Mth + 1, 0)
   E_Mth = Month(Last_date)
   my_day = Day(Last_date)
    x = Mth = E_Mth
    y = Day(sh.Cells(I, 1)) = dy Or Day(sh.Cells(I, 1)) = my_day
    z = sh.Cells(I, 1) <> sh.Cells(I + 1, 1)
    If x * y * z = -1 Then
    sh.Cells(I + 1, 1).Select
    sh.Cells(I + 1, 1).EntireRow.Insert , xlDown
    sh.Cells(I + 1, 1) = TOT
    sh.Cells(I + 1, 1).Resize(, 17).Interior.ColorIndex = 6
    sh.Cells(I + 1, 2).Resize(, 16).Formula = _
    "=SUM(B" & t & ":B" & I & ")"
    t = I + 2: I = I + 1: k = k + 1: New_ro = New_ro + 1

    End If  'x * y * z
     
  End If 'isdate
  Next
  
 New_ro = sh.Cells(Rows.Count, 1).End(3).Row + 1
  sh.Cells(New_ro, 1) = TOT
  sh.Cells(New_ro, 1).Resize(, 17).Interior.ColorIndex = 6
  sh.Cells(New_ro, 2).Resize(, 16).Formula = _
    "=SUM(B" & t & ":B" & New_ro - 1 & ")"
   sh.Range("A4:Q" & New_ro).Value = _
   sh.Range("A4:Q" & New_ro).Value
    clear_last
    A = Application.CountIf(sh.Range("A:A"), TOT)
   MsgBox "I Enter " & A & " " & _
   IIf(A = 1, TOT, "Recordes") & " For you " & Chr(10) & _
   " I hope you say thank you : " & """SALIM"""
End Sub
'+++++++++++++++++++++++++++++++++++
Sub clear_last()
Dim m%, Ro%, XX%, d1, d2, kk%, cnt%
 Dim dat1, m1
 Set sh = ActiveSheet
 m = sh.Cells(Rows.Count, 1).End(3).Row - 1
 For XX = 4 To m
 If sh.Cells(XX, 1) = TOT Then
  Ro = sh.Cells(XX, 1).Row
 End If
  Next
  For kk = Ro + 1 To m
  
   m1 = Month(sh.Cells(kk, 1))
   d1 = Day(sh.Cells(kk, 1))
   d2 = Day(DateSerial(Year(sh.Cells(kk, 1)), m1 + 1, 0))
   If d1 <> dy Or d1 <> d2 Then
     cnt = cnt + 1
   End If
   
  Next
  If cnt > 0 Then Cells(m + 1, 1).EntireRow.Delete
End Sub

'++++++++++++++++++++++++++++++++++++++
Sub CLEAR_TOTALS()
Dim k%, B%
Set sh = ActiveSheet
B = Application.CountIf(sh.Range("A:A"), TOT)
Max_ro = sh.Cells(Rows.Count, 1).End(3).Row
 sh.Range("A4:Q" & Max_ro).Interior.ColorIndex = xlNone
 For I = Max_ro To 4 Step -1
  If Not IsDate(sh.Cells(I, 1)) Then
 sh.Cells(I, 1).EntireRow.Delete
   k = k + 1
  End If
 Next
 
  MsgBox "I Clear " & B & " " & _
   IIf(B = 1, TOT, "Recordes") & " For you " & Chr(10) & _
   " I hope you say thank you : " & """SALIM"""
End Sub





الملف مرفق


 
 
 
  Ali_hani_Super_1.xlsm   تحميل xlsm مرات التحميل :(5)
الحجم :(1495.163) KB


11-08-2020 01:35 مساء
مشاهدة مشاركة منفردة [6]
salim
خبير معتمد
rating
معلومات الكاتب ▼
تاريخ الإنضمام : 22-08-2017
رقم العضوية : 43
المشاركات : 853
الجنس : ذكر
تاريخ الميلاد : 1-5-1989
الدعوات : 1
يتابعهم : 13
يتابعونه : 33
قوة السمعة : 6607
عدد الإجابات: 67
 offline 
look/images/icons/i1.gif تعديل كود اضافة صف للإجمالى مرتين خلال نفس الشهر
ملاحظة الأفضل استبدال في هذا الجزء من الكود (الصورة)
ما يوجد في المربع الأحمر بما يوجد في المربع الأزرق
و ذلك لضمان ان التنسيق مكتمل 100 %
لأن  OR تسمح بعمل الماكرو  ولو كان شرطاً واحداَ صحيحاً اما And فلا تسمح الا اذا كانت كل الشروط صحيحة
لا تنس اضافة Else  لان بدونها لا يعمل الماكرو
oJQ0z_hani_ali
 
 
 



الصفحة 1 من 2 < 1 2 > الأخيرة »


الكلمات الدلالية
تعديل ، اضافة ، للإجمالى ، مرتين ، خلال ، الشهر ،


 










اخلاء مسئولية: يخلى منتدى أكاديمية الصقر للتدريب مسئوليته عن اى مواضيع او مشاركات تندرج داخل الموقع ويحثكم على التواصل معنا ان كانت هناك اى إنتهاكات تتضمن اى انتهاك لحقوق الملكية الفكرية او الادبية لاى جهة - بالتواصل معنا من خلال نموذج مراسلة الإدارة .وسيتم اتخاذ الاجراءات اللازمة.
سياسة النشر: التعليقات المنشورة لا تعبر عن رأي منتدى أكاديمية الصقر للتدريب ولا نتحمل أي مسؤولية قانونية حيال ذلك ويتحمل كاتبها مسؤولية النشر.

الساعة الآن 05:17 صباحا