أخي الكريم فتحي
ما يظهر في الصور يظهر أنك لديك أكواد تعمل بدون مشاكل وأكواد تعمل بمشاكل
أين السؤال في الموضوع !!!!!!!؟

تعديل اربع ازرار التي بهم مشاكل محتاج اخليهم يشتغلو صح زي ( NumLock )
اكيد جربت الملف لو تجرب ازرار الـ NumLock مش هيكون في مشاكل
لو جربت باقي الــ CapsLock - ScrollLock هتلاقي في خلل في وظيفة الكود من رغم كاتب الكود صح زر رقم 2 سواء في ScrollLock او CapsLock لو ضغط مرة يشتغل و لو ضغط مرة اخرى يعطي امر ايضاً ان اللمبة تنطفي المفروض كل ما ادوس على الزر رقم 2 يفضل منور زي ما هو
و زر رقم 3 المفروض يطفي اللمبة و لو دوست علية تاني بردو المفروض يديني نفس النتيجة بس الزر رقم 3 مش شغال اصلا

قم بمسح كل ما لديك من الأكواد وأدرج موديول جديد ، حيث قمت بعمل توليفة تعمل للثلاثة أزرار ..

Private Const VER_PLATFORM_WIN32_WINDOWS = 1
Private Const VK_NUMLOCK = &H90
Private Const VK_CAPITAL = &H14
Private Const VK_SCROLL = &H91
Private Const KEYEVENTF_EXTENDEDKEY = &H1
Private Const KEYEVENTF_KEYUP = &H2
           
Private Type OSVERSIONINFO
    dwOSVersionInfoSize As Long
    dwMajorVersion As Long
    dwMinorVersion As Long
    dwBuildNumber As Long
    dwPlatformId As Long
    szCSDVersion As String * 128
End Type

Private Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)
Private Declare Function GetKeyboardState Lib "user32" (pbKeyState As Byte) As Long
Private Declare Function SetKeyboardState Lib "user32" (lppbKeyState As Byte) As Long

Function CheckOnOff(ByVal v)
    ReDim KeyboardBuffer(256) As Byte
    GetKeyboardState KeyboardBuffer(0)
    If KeyboardBuffer(v) And 1 Then CheckOnOff = True Else CheckOnOff = False
End Function

Public Sub ToggleButton(ByVal TurnOn As Boolean, ByVal v)
    Dim bytKeys(255) As Byte, bOn As Boolean, typOS As OSVERSIONINFO
    GetKeyboardState bytKeys(0)
    bOn = bytKeys(v)
    If bOn <> TurnOn Then
        If typOS.dwPlatformId = VER_PLATFORM_WIN32_WINDOWS Then
            bytKeys(v) = 1
            SetKeyboardState bytKeys(0)
        Else
            keybd_event v, &H45, KEYEVENTF_EXTENDEDKEY Or 0, 0
            keybd_event v, &H45, KEYEVENTF_EXTENDEDKEY Or KEYEVENTF_KEYUP, 0
        End If
    End If
End Sub

'------------------------------------------------------------------------

Sub NumLockToggle()
    If CheckOnOff(VK_NUMLOCK) = False Then NumLockON Else NumLockOFF
End Sub

Sub NumLockON()
    ToggleButton True, VK_NUMLOCK
End Sub

Sub NumLockOFF()
    ToggleButton False, VK_NUMLOCK
End Sub

'------------------------------------------------------------------------

Sub CapsLockToggle()
    If CheckOnOff(VK_CAPITAL) = False Then CapsLockON Else CapsLockOFF
End Sub

Sub CapsLockON()
    ToggleButton True, VK_CAPITAL
End Sub

Sub CapsLockOFF()
    ToggleButton False, VK_CAPITAL
End Sub

'------------------------------------------------------------------------

Sub ScrollLockToggle()
    If CheckOnOff(VK_SCROLL) = False Then ScrollLockON Else ScrollLockOFF
End Sub

Sub ScrollLockON()
    ToggleButton True, VK_SCROLL
End Sub

Sub ScrollLockOFF()
    ToggleButton False, VK_SCROLL
End Sub

تسلم ايدك يا استاذ ياسر بارك الله فيك
منك نستفيد مما علمك الله تم حل مشكلة الازرار و الكود يعمل بكفائة
و للتوضيح اكتر ان الكود كما سبق و قلت انة يعمل على اوفيس 32
و قمت بوضع كلمة PtrSafe بعد كلمة Declare
نعدل ثلاث اسطر مثل
Private Declare PtrSafe Function و باقي الاسطر
لكي يعمل على اوفيس 64
وهذا للعلم اذا واجه احد هذة المشكلة
و اشكرك جدا يا استاذ ياسر

بارك الله فيك أخي العزيز فتحي والحمد لله أن تم المطلوب على خير والحمد لله الذي بنعمته تتم الصالحات