تصميم فورم مواقــيت الصـلاة لجمـيع مـدن العالـم

Sub Test()

    Const sURL As String = "https://www.masrawy.com/Islameyat/Prayer-Times"

    Dim v, html As MSHTML.HTMLDocument, ws As Worksheet, post As Object, sID As String, nURL As String, i As Long, c As Long



    Set ws = ThisWorkbook.Worksheets("Sheet1")

    Set html = GetHTML(sURL)

    Set post = html.querySelectorAll("div .wrapperDropdown[tabindex='1'] li")

    c = 1

            

    With post

        For i = 0 To .Length - 1

            ws.Cells(1, c).Value = .Item(i).innerText

            sID = .Item(i).getElementsByTagName("a")(0).getAttribute("countryid")

            ws.Cells(1, c + 1).Value = sID

            nURL = "https://www.masrawy.com/Islameyat/GetCityList?countryId=" & sID

            v = GetCities(nURL)

            ws.Cells(2, c).Resize(UBound(v, 1), UBound(v, 2)).Value = v

            c = c + 2

        Next i

    End With

End Sub



Function GetCities(ByVal sURL As String)

    Dim html As MSHTML.HTMLDocument, post As Object, i As Long

    Set html = GetHTML(sURL)

    Set post = html.querySelectorAll("#ulCityList li")

    With post

        ReDim a(1 To .Length, 1 To 2)

        For i = 0 To .Length - 1

            a(i + 1, 1) = .Item(i).innerText

            a(i + 1, 2) = .Item(i).getElementsByTagName("a")(0).getAttribute("cityid")

        Next i

    End With

    GetCities = a

End Function



Function GetHTML(ByVal sURL As String) As HTMLDocument

    Dim http As MSXML2.XMLHTTP60, html As MSHTML.HTMLDocument

    Set http = New MSXML2.XMLHTTP60

    Set html = New MSHTML.HTMLDocument

    With http

        .Open "Get", sURL, False

        .send

        html.body.innerHTML = .responseText

    End With

    Set GetHTML = html

End Function