السلام عليكم ورحمة الله وبركاته

إخواني الكرام أقدم لكم كود يمكنك من إرسال رسائل بريد إلكتروني عبر الـ Gmail بطريقة بسيطة ، كل ما عليك هو وضع الكود التالي في موديول عادي

Option Explicit

Sub Send_Gmail_Using_CDO()
    Dim folder      As Variant
    Dim cdoMsg      As Object
    Dim file        As String
    Dim cdoNS       As String
    Dim htmlMsg     As String
    Dim password    As String
    Dim strBCC      As String
    Dim strCC       As String
    Dim strMsg      As String
    Dim strSubj     As String
    Dim strTo       As String
    Dim userEmail   As String
    Dim strBody     As String
    
    'الإيميل الذي سيرسل إليه
    strTo = "anyone@gmail.com"
    
    'عنوان الرسالة
    strSubj = "This Is The Subject Line"
    strMsg = ""
    strCC = ""
    strBCC = ""
    
    'مضمون الرسالة
    strBody = "Hello My Friend" & vbCrLf & "How Are You Doing?"
    
    'معلومات بريدك الاسم وكلمة السر
    userEmail = "my_gmail@gmail.com"
    password = "my_pass"

    cdoNS = "http://schemas.microsoft.com/cdo/configuration/"
    Set cdoMsg = CreateObject("CDO.Message")

    With cdoMsg
        .To = strTo
        .Subject = strSubj
        .From = userEmail
        .CC = strCC
        .BCC = strBCC
        .TextBody = strBody

        With .Configuration.Fields
            .Item(cdoNS & "smtpusessl") = True
            .Item(cdoNS & "smtpauthenticate") = 1
            .Item(cdoNS & "sendusername") = userEmail
            .Item(cdoNS & "sendpassword") = password
            .Item(cdoNS & "smtpserver") = "smtp.gmail.com"
            .Item(cdoNS & "sendusing") = 2
            .Item(cdoNS & "smtpserverport") = 465
            .Item(cdoNS & "smtpconnectiontimeout") = 60
            .Update
        End With

        .Send
    End With
End Sub

في الكود يوجد تعليقات على الأسطر التي ستقوم بتعديلها حيث يتم كتابة إيميل المرسل إليه ، وكتابة عنوان للرسالة ، وكتابة مضمون الرسالة ، وكتابة البيانات الخاصة بالإيميل المطلوب إرسال الرسالة منه

كما يجب التنبية ان شركة جوجل في الاونه الاخيرة قامت بزيادة حماية البريد الالكترونى ولكي يعمل هذا الكود في ارسال اى ايمال يجب الذهاب الى الرابط التالى بعد تسجيل الدخول على الايمال المرسل منه
https://myaccount.google.com/lesssecureapps?pli=1
ثم تفعيل ارسال البريد بحماية اقل والتى بدورها انصح ان الايمال المسجل للارسال يكون غير الايمال الشخصي حتى لا يتعرض لاى اختراق

رابط الملف من هنا

أخوكم في الله / ياسر خليل أبو البراء